今天小编继续给大家介绍高手经典策略：日均ATR波动性突破和ORB失败突破。和以往一样，首先需要强调一下，文中提供的模型不要直接用于实盘，仅仅给大家作为思路拓展使用。大家可以根据这些经典的策略进行改编，结合平时的交易经验，形成自己的交易策略。本文中的经典策略均来自于网络，是根据网络中常见的方式改写的。

*日均ATR波动性突破

 真实波动幅度指标（ATR）是一定时间周期内价格波动幅度的移动平均值，是显示市场变化率的指标，由威尔德（Welles Wilder）在《技术交易系统中的新概念》一书中首次提出，目前已成为众多指标经常引用的技术量。

当一定幅度的ATR波动性幅度已经发生，往往意味着日内波动的方向将朝着这个已经完成一定幅度ATR的方向继续发展，比较的基准，可以是开盘价，也可以是日内创下的新高、新低记录位置。

作为波动率测度指标，ATR自身的波动较小,更适合用来对趋势行情加以确认。同时，其能更快更稳定的度量当前价格运行方向上的正常波动状态，从而更好的对价格趋势加以确认。

具体交易原则如下：

当一定幅度的ATR波动性幅度已经发生，大概率下，日内波动方向朝着这个已经完成一定ATR幅度的方向继续发展，可以是开盘价，也可以是日内已经创下的新高、新低记录位置。

区间上下轨的确定：

日均ATR突破基于今日开盘价与过去N个交易日平均ATR的关系；

上轨＝今日开盘价+N个交易日平均ATR*M；

下轨＝今日开盘价-N个交易日平均ATR*M；

买卖信号：

1、突破上轨,买入开仓做多;

2、突破下轨,卖出开仓做空。

由此，我们得出日均ATR波动性突破的策略源码：

N:=26;//简单定义26周期的ATR

TR:=MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));

//求最高价减去最低价，一个周期前的收盘价减去最高价的绝对值，一个周期前的收盘价减去最低价的绝对值，这三个值中的最大值

ATR:=MA(TR,N),COLORYELLOW;//求N个周期内的TR的简单移动平均

M:=1/2;//简单定义M倍的ATR

SG:VALUEWHEN(DAYBARPOS=1,O)+M*ATR;//以当天开盘价为基准，加0.5倍ATR作为上轨

XG:VALUEWHEN(DAYBARPOS=1,O)-M*ATR;//以当天开盘价为基准，减0.5倍ATR作为下轨

CROSSUP(C,SG),BPK;//价格突破波动区间上轨，反手做多

CROSSDOWN(C,XG),SPK;//价格跌破波动区间下轨，反手做空

CLOSEMINUTE<=10,CLOSEOUT;//收盘前10分钟清仓

AUTOFILTER;

//以上模型仅仅用来示范演示使用，依此入市，风险自负。

下图为将这一模型加载到K线上后的效果图：

*ORB失败突破

 

ORB突破交易最早于1988年由美国基金经理托比提出，它通过衡量开盘价与最高价、最低价距离的较小者，为失败突破幅度，后市一旦超出这个幅度，就认为是真正的突破。在实际应用过程中，早盘的突破、窄幅波动后的突破，可以作为有效的过滤条件。

 

ORB失败突破交易具体交易原则如下：

区间上下轨的确定：

基于过去N个交易日ORB指标；

上轨＝今日开盘价+N天ORB*M；

下轨＝今日开盘价-N天ORB*M；

过去失败的次数多，下一次成功的概率就比较高，N通常取10。

买卖信号：

1、突破上轨,买入开仓做多;

2、突破下轨,卖出开仓做空。

 

由此，我们得出ORB突破交易的策略源码：

N:=10;

M:=1.2;

NN:=DAYBARPOS;//当日K线根数

DN:=HHV(NN,NN+226);//求当前周期上每天的总K线根数

OO:=VALUEWHEN(NN=1,OPEN);//当日开盘价

HH:=HHV(HIGH,NN);//当日最高价

LL:=LLV(LOW,NN);//当日最低价

HT:=REF(HH,NN);//昨高

LT:=REF(LL,NN);//昨低

CT:=REF(C,NN);//昨收

ORB:=MIN(ABS(HT-CT),ABS(LT-CT));//定义ORB变量，取昨高到昨收距离、昨低到昨收距离的最小值

DTN:=N*DN;//N日的K线根数

BAND:=VALUEWHEN(NN=1,MA(ORB*M,DTN));//N天ORB*M

SG:OO+BAND;//以开盘价为基础，加N天的ORB*M波动幅度，作为上轨

XG:OO-BAND;//以开盘价为基础，减N天的ORB*M波动幅度，作为下轨

CROSSUP(C,SG),BPK;//价格突破上轨，反手做多

CROSSDOWN(C,XG),SPK;//价格突破下轨，反手做空

CLOSEMINUTE<=10,CLOSEOUT;//收盘前10分钟清仓

AUTOFILTER;

//以上模型仅仅用来示范演示使用，依此入市，风险自负。

 

下图为将这一模型加载到K线上后的效果图：

日均ATR波动性突破和ORB失败突破仅仅是交易思路，不能直接用来进行实盘交易。投资者还需在此基础上结合止损止盈、品种特点以及由自身经验判断出的市场波动特质，搭建属于自己的交易策略。